Font Size:

MEPS Sample Persons In-Scope for Part of the Year: Identification and Analytic Considerations

April 2005

by Steven Machlin and William Yu

Table of Contents

Introduction
Frequency of Part-Year Sample Persons
Reasons for Part-Year In-Scope
Characteristics of Part-Year versus Full-Year In-Scope Sample Persons
Identification of Part-Year In-Scope Cases in MEPS Data Files
Handling of Variables Affected by Being Out of Scope Part Year
Summary
Appendix A: SAS Code to Distinguish Full-Year from Part-Year In-Scope Observations
Appendix B: SAS Code Used to Generate Data in This Report

Introduction

The Medical Expenditure Panel Survey (MEPS) is a longitudinal survey that covers the United States civilian noninstitutionalized population. The survey consists of five interviews conducted over a two and a half year period. The data collected in these interviews are designed to jointly cover a two-year period for sample respondents. For example, data for the sixth MEPS panel covers the period from January 1, 2001 through December 31, 2002. Each of the five interviews conducted for the panel asked about all health care utilization and associated expenditures for a specific period of time, and these periods cumulatively covered the two-year period. MEPS data are used to produce annual estimates (annual files contain pooled data from two consecutive panels) as well as for two-year longitudinal analyses.

Users of MEPS data should be aware that the survey collects data for all sample persons who were in the survey target population at any time during the survey period. In other words, a small proportion of individuals in MEPS analytic files are not members of the survey target population (i.e., civilian noninstitutionalized) for the entire survey period. For example, approximately 3 percent of MEPS sample persons in the MEPS annual 2002 data file (HC-070) were in-scope for the survey for part but not all of the year. These persons include those who had periods during which they lived in an institution (e.g., nursing home or prison), were in the military, or lived out of the country, as well as those who were born (or adopted) into MEPS sample households or died during the year. They are considered respondents to the survey and are included in MEPS data files with positive person weights, but no data were collected for the periods they were not in-scope and their annual data for variables like health care utilization and expenditures reflect only the part of the year they were in-scope for the survey. Persons who are in-scope for only part of the year should not be confused with non-respondents. Sample persons who are classified as non-respondents to one or more rounds of data collection (i.e., initial non-respondents and drop outs over time) are not included in MEPS annual files, and survey weights for full-year respondents are inflated through statistical adjustment procedures to compensate for both full and part-year nonresponse (for more details, see Cohen et al., 1999).

The purpose of this fact sheet is to describe MEPS sample persons who were in the target population for only part of the year, explain how to identify them in MEPS annual files, and discuss considerations when determining whether to include or exclude these persons from analyses. The data and examples presented are based on the MEPS 2002 full year consolidated file (HC-070).

Return To Table Of Contents

Frequency of Part-Year Sample Persons

The 2002 MEPS annual consolidated file contains 37,418 sample observations with positive person weights (i.e., those with a person weight of 0 are used for family analyses and are not relevant to this fact sheet). The overwhelming majority of these cases (97.3 percent) were in-scope for all of 2002, while 2.7 percent (1,012 cases) were only in-scope for part of the year (table 1). As would be expected, those who were in-scope for part of the year were in-scope on average for approximately half the year (average of 174 days).

**Table 1: Sample Sizes and Reasons for Part-Year Data, 2002 MEPS**
Characteristics	Sample Size	Percent of Sample	Distribution of Part-Year by Reason
Total	37,418	100.0%	–
Full Year	36,406	97.3%	–
Part Year	1,012	2.7%	100.0%
New Born	485	1.3%	48.0%
Died	223	0.6%	22.0%
Out of Country	173	0.5%	17.1%
Institutionalized¹	94	0.3%	9.3%
Military	35	0.1%	3.5%
Unknown reason	2	0.0%	0.2%

¹Healthcare institution for nearly three-fourths of group.

Return To Table Of Contents

Reasons for Part-Year In-Scope

Table 1 shows the distribution of reasons that sample persons were in-scope for only part of the year. Newborns accounted for nearly half of these sample persons (48 percent) while death during the year accounted for an additional 22 percent. The next most common reasons were living parts of the year out of the country (17 percent) or in an institution (9 percent). Finally, a small proportion of these sample persons served in the military for part of the year (3.5 percent).

Return To Table Of Contents

Characteristics of Part-Year versus Full-Year In-Scope Sample Persons

MEPS annual estimates are for persons who were in the target population at any time during the year. In 2002, an estimated 280.3 million persons were in the U.S. civilian noninstitutionalized population for the entire year while an estimated additional 7.8 million were in the target population for part of the year. In the aggregate, this results in an estimated 288.2 million people in-scope at any time during the year.

Despite the fact that their data reflect health care use for only part of the year, average health care expenses for sample persons in-scope for only part of the year were substantially higher than for sample persons in-scope all year ($7,782 versus $2,674). This overall comparison, however, masks substantial variation among subgroups of part year in-scope sample persons (table 2). Not surprisingly, persons who died or lived in an institution for part of the year tended to be older, were more likely to be in fair or poor health, and had substantially higher average expenditures than the full-year sample persons or other part-year subgroups. Conversely, average expenses were lower for persons in the military or out of the country part of the year, which is likely because they are generally younger, healthier, and only include expenses on average for about half the year. Finally, despite being in-scope for only part of the year, average expenses for newborns were similar to those for the full-year group, which is attributable to extremely high inpatient hospital expenses for a relatively small number of births with complications and extended hospital stays (hospital expenses identified in MEPS for births without complications are linked to the mother rather than the newborn).

Return To Table Of Contents

**Table 2: Selected Characteristics by Time In-Scope and Reason for Part-Year Data, 2002 MEPS**
Population Estimate (civilian noninstiutional)			Expenditures		Fair/Poor Health¹		Age at 12/31/02²
Characteristics	Total	S.E.	Mean	S.E.	Mean	S.E.	Mean	S.E.
Total	288,181,763	5,847,687	$2,813	$59	10.7%	0.3%	36.3	0.24
Full Year	280,338,651	5,750,371	$2,674	$53	10.5%	0.3%	36.5	0.23
Part Year	7,843,112	333,104	$7,782	$919	17.5%	1.5%	31.4	1.41
New Born	3,341,367	192,256	$2,857	$1,044	2.1%	0.7%	0.00	0.00
Death	1,864,914	149,154	$18,973	$2,292	41.6%	3.7%	68.5	1.36
Out of Country	1,201,738	143,590	$425	$114	5.5%	1.8%	29.0	1.89
Institutionalized³	1,139,822	151,773	$13,634	$2,773	39.5%	6.2%	66.8	2.74
Military	286,986	49,117	$202	$59	1.6%	1.6%	25.7	1.97

¹Based on first in-scope interview in year with response to health status question.
²Age at end of year or last round in-scope.
³Healthcare institution for nearly three-fourths of group.

Return To Table Of Contents

Identification of Part-Year In-Scope Cases in MEPS Data Files

Appendix A provides SAS programming code showing how to use MEPS 2002 data files (annual and longitudinal) to distinguish persons who were in-scope for the survey all year (annual files) or all two years (longitudinal analyses) versus only part of the period covered. To distinguish persons who were in-scope for the survey all year versus part of the year (annual files) and also ascribe reasons for being in-scope only part-year, it is necessary to work with round-specific person status variables (PSTATS31, PSTATS42, PSTATS53), in-scope variables (INSCOP31, INSCOP42, INSCOP02), and variables indicating the beginning dates (BEGRFM31 BEGRFD31 BEGRFY31 BEGRFM42 BEGRFD42 BEGRFY42 BEGRFM53 BEGRFD53 BEGRFY53) and ending dates (ENDRFM31 ENDRFD31 ENDRFY31 ENDRFM42 ENDRFD42 ENDRFY42 ENDRFM53 ENDRFD53 ENDRFY53) of interview reference periods. The detailed SAS code that uses these variables to classify cases and generate the data in this report are provided in Appendix B. Here is a general overview of the steps involved:

1) For each of the sample observations with a positive person weight (PERWT02F>0), we first computed the number of in-scope days during the year. Observations with 365 in-scope days were considered in-scope full year while all the remaining observations were initially classified as in-scope part year (slight modification described in 3 below).

2) Then we assigned reasons for part-year status. For the small number of persons who had more than one reason they were out of scope during the year, we classified reason based on the following hierarchy: “died,” “new born,” “institutionalized,” “military,” “moved within U.S.,” “out of country,” and “unknown.” For example, sample persons who lived in a nursing home for part of the year and died in 2002 were classified as “died” rather than “institutionalized.”

3) Finally, an adjustment was made for persons who moved from one MEPS sample household to another during the year. While these persons were technically in-scope all year, they initially appeared to have less than 365 in-scope days because the reference period dates for their original household are superseded by those for the household into which they moved. Therefore, we changed in-scope days for these persons to 365 and regrouped them into the “full year” group (thereby eliminating the “moved within U.S. group” listed in 2 above).

Return To Table Of Contents

Handling of Variables Affected by Being Out of Scope Part Year

Many questions in the MEPS survey instrument are asked at each interview and apply to the interview date or a reference period for the interview (e.g., date from last to current interview). Persons who were out of scope at the time of an interview are assigned a value of -1 (inapplicable) for most variables. Therefore, if persons who were in-scope only part of the year are to be included in the analysis, it is important for analysts to make an informed judgment about how to maximize completeness of the data for those cases. It is common practice at AHRQ to use the most recently completed data prior to the person going out of scope. For example, health status is collected for each individual at each interview. If a person was not in scope in round 3, then the response for the comparable health status variable in round 2 (RTHLTH42) would be used if available. Another important variable to complete for analyses is age. One approach to complete this variable is to start with a variable for age at the end of the year (e.g., AGE02X in 2002 full year files). If this variable was coded as -1 because a person was not in scope at the end of the year, then use the most recent value for age (either AGE42X or AGE31X).

Return To Table Of Contents

Summary

In 2002, approximately 3 percent of MEPS sample persons used to produce annual estimates were in-scope for the survey for only part of the year. It is important that analysts of MEPS insurance, utilization, and expenditure data understand that overall MEPS estimates for these data are based only on periods that sample persons were part of the civilian noninstitutionalized population. While the overwhelming majority of MEPS sample persons are in the survey target population for the entire year, those in-scope for only part of the year have a small but noticeable impact on national estimates. For example, the estimated average health care expenditures per person in 2002 based on all MEPS sample persons was $2,813. This estimate would decrease to $2,674 if persons in scope for only part of the year were excluded. This decrease is attributable to substantially higher expenses for persons who died during the year or lived in an institution for part of the year.

There are several reasons that some sample persons are only in-scope for part of the year, and characteristics of part-year in-scope sample persons vary dramatically according to these reasons. Consequently, whether to include all, some, or none of the part-year in-scope sample persons may vary according to the research question. Analysts must also consider how to complete data for key variables when persons who were in-scope for part of the year are included.

Return To Table Of Contents

Reference

Cohen, S. B., DiGaetano, R., and Goksel, H. Estimation Procedures in the 1996 Medical Expenditure Panel Survey Household Component. Rockville, Md.: Agency for Health Care Policy and Research, 1999. MEPS Methodology Report No. 5. AHRQ Pub. No. 99-0027.

Appendix A: SAS Code to Distinguish Full-Year from Part-Year In-Scope Observations

2002 Annual File

Proc format;

Value fullyrfmt 1=’Full Year’ 2=’Part Year’;

Data A2002; set input.h70 (keep=inscop31 inscop42 inscop53 inscop02 panel02

begrfy31 perwt02f);

If perwt02f>0;

If panel02=7 then do; /* persons in year 1 of the survey, panel 7 */

If (inscop31=1 & inscop42=1 & inscop02=1) then fullyr=1; else fullyr=2;

end;

If panel02=6 then do; /* persons in year 2 of the survey, panel 6 */

If ( (inscop31 in (1,3) & begrfy31 < 2002) & inscop42=1 & inscop53=1)

then fullyr=1; else fullyr=2;

end;

run;

Panel 6 Longitudinal (2001-2002)

Proc format;

Value full2yrfmt 1=’Full 2 Years’ 2=Not full 2 Years’;

data in01; set input.h60; /*MEPS annual 2001 file*/

keep dupersid inscop1 inscop2;

inscop1=inscop31;

inscop2=inscop42;

if panel01=6;

run;

data in02; set input.h70; /*MEPS annual 2002 file*/

keep dupersid inscop3 inscop4 inscop5;

inscop3=inscop31;

inscop4=inscop42;

inscop5=inscop53;

if panel02=6;

run;

proc sort data=in01; by dupersid;

proc sort data=in02; by dupersid;

proc sort data=input.h71; out=h71a; by dupersid; /*MEPS panel 6 longitudinal file*/

/*merge panel6 year1 and year2 files (in01 and in02) by dupersid*/

data mrgp6; merge in01 (in=in1) in02 (in=in2); by dupersid;

/*merge panel6 w-year file to longitudinal file by dupersid*/

data mrgp6x; merge mrgp6 (in=in1) h71a (in=in2); by dupersid;

If ( inscop1=1 and inscop2=1 and inscop3=1 and inscop4=1 and inscop5=1)

then full2yr=1; else full2yr=2; /*1=inscope full 2 years, see proc format statement*/

run;

Return To Table Of Contents

Appendix B: SAS Code Used to Generate Data in This Report

libname input1 'J:\PUF SAS Files\SAS V8';*;
*;
proc format;
value grpfmt 1='Full Year' 2='Part Year';
value catfmt 1='Full Year' 2='Death' 3='New Born' 4='Institution'
       5='Military' 6='Out of Country' 7='Others';
*;
data A2002; set input1.h70(keep=inscop31 inscop42 inscop02 pstats31 pstats42 pstats53 perwt02f totexp02 begrfm31 begrfd31 begrfy31 begrfm42 begrfd42 begrfy42 begrfm53 begrfd53 begrfy53 endrfm31 endrfd31 endrfy31 endrfm42 endrfd42 endrfy42 endrfm53 endrfd53 endrfy53 age31x age42x age02x rthlth31 rthlth42 rthlth53 varstr varpsu);
if perwt02f>0;
Array y{3} inscop31 inscop42 inscop02;
Array p{3} pstats31 pstats42 pstats53;
Array z{3} days31 days42 days53;
Array u{3,3} begrfm31 begrfd31 begrfy31
       begrfm42 begrfd42 begrfy42
       begrfm53 begrfd53 begrfy53;
Array v{3,3} endrfm31 endrfd31 endrfy31
       endrfm42 endrfd42 endrfy42
       endrfm53 endrfd53 endrfy53;
if v{3,3}=2003 then do; v{3,1}=12; v{3,2}=31; v{3,3}=2002; end;
if u{1,3}=2001 then do; u{1,1}=1; u{1,2}=1; u{1,3}=2002; end;
*;
Do i=1 to 3; /* compute round specific days in scope */
z{i}=0;
if (y{i} in (1,2,3,4)) then do; /* in scope */
  /* if all reference periods data available */
  if (u{i,1}>0 & u{i,2}>0 & v{i,1}>0 & v{i,2}>0) then do;
if (i=1 or i=2) & (u{i+1,1}>0 & u{i+1,2}>0) then do;
if (mdy(v{i,1},v{i,2},v{i,3})>mdy(u{i+1,1},u{i+1,2},u{i+1,3})) then do;
   v{i,1}=u{i+1,1}; v{i,2}=u{i+1,2}; /* overlapping reference periods */
end;
end;
z{i}=mdy(v{i,1},v{i,2},v{i,3})-mdy(u{i,1},u{i,2},u{i,3});
  end;
  else if (u{i,1}>0 & v{i,1}>0) then do; /* beg. & ending month>0 */
if u{i,2}<=0 & v{i,2}>0 then do; /* beg. ref day unknown */
if u{i,1}<v{i,1} then z{i}=mdy(v{i,1},v{i,2},v{i,3})-mdy(u{i,1},16,u{i,3});
if u{i,1}=v{i,1} then z{i}=(v{i,2}-1)/2;
end;
if u{i,2}>0 & v{i,2}<=0 then do; /* ending ref day unknown */
if u{i,1}<v{i,1} then z{i}=mdy(v{i,1},16,v{i,3})-mdy(u{i,1},u{i,2},u{i,3});
if u{i,1}=v{i,1} then z{i}=(31-u{i,2})/2;
end;
  end;
else z{i}=.; /* beginning or ending month<=0 */
end;
end;
*;
eligdays=sum(days31,days42,days53)+1;
*;
if rthlth31 ne -1 then rthlth=rthlth31;
else if rthlth42 ne -1 then rthlth=rthlth42;
  else if rthlth53 ne -1 then rthlth=rthlth53;
hstatus=0; if rthlth in (4,5) then hstatus=1;
if age02x>=0 then age=age02x;
else if age42x>=0 then age=age42x;
  else if age31x>=0 then age=age31x;
keep eligdays hstatus age varstr varpsu pstats31 pstats42 pstats53 inscop02
   perwt02f totexp02;
proc sort data=a2002; by varstr varpsu;
*;
Data a; set a2002;
if eligdays=365 then do; group=1; category=1; end; /* full year */
else do; group=2;
if pstats31 in (23,24,31) or pstats42 in (23,24,31) or
  (pstats53 in (23,24,31) & inscop02 ne 1) then category=2; /* part year - death */
else if pstats31=51 or pstats42=51 or (pstats53=51 & inscop02=3)
  then category=3; /* part year - new born */
else if pstats31 in (21,22,32) or pstats42 in (21,22,32) or
  (pstats53 in (21,22,32) and inscop02 ne 1) then category=4; /*Part Year-Health Care Institution*/
else if pstats31 in (33,36) or pstats42 in (33,36) or
  (pstats53 in (33,36) and inscop02 ne 1) then category=4; /*Part Year-Non-health Care Institution*/
else if pstats31 in (12,14,35,74) or pstats42 in (12,14,35,74) or
  (pstats53 in (12,14,35,74) & inscop02 ne 1) then category=5; /*Part Year-Military*/
else if pstats31 in (11,13,41) & pstats42 in (11,13,41,44) & inscop02=1
  then do; eligdays=365; group=1; category=1; end; /*Full Year, Moved within US*/
else if (pstats31 in (34,42,44) or pstats42 in (34,42,44) or pstats53 in (34,42,44))
  then category=6; /*Part Year-Out of Country*/
else category=7; /*Part Year-Others*/
end;
wgt=1;
*;
proc descript data=work.a filetype=sas design=wr;
nest varstr varpsu/missunit;
weight perwt02f;
var wgt;
tables group category;
subgroup group category;
levels 2 7;
setenv topmgn=0;
print nsum="Sample size" total setotal/
style=NCHS totalfmt=f12.0 setotalfmt=f12.0;
title "Table 1: Summary for PERWT02F - MEPS 2002 Full Year File";
rformat group grpfmt.; rformat category catfmt.;
*;
proc descript data=work.a filetype=sas design=wr;
nest varstr varpsu/missunit;
weight perwt02f;
var totexp02 eligdays hstatus age;
tables group category;
subgroup group category;
levels 2 7;
setenv topmgn=0;
print nsum="Sample size" wsum="Weighted size" mean semean/
style=NCHS wsumfmt=f12.0 meanfmt=f10.3 semeanfmt=f10.3;
title "Table 2: Summary - MEPS 2002 Full Year File";
rformat group grpfmt.; rformat category catfmt.;
run;

Suggested Citation:
Machlin, S. and Yu, W. MEPS Sample Persons In-Scope for Part of the Year: Identification and Analytic Considerations. April 2005. Agency for Healthcare Research and Quality, Rockville, MD. https://meps.ahrq.gov/about_meps/hc_sample.shtml

Return To Table Of Contents

MEPS HOME . CONTACT MEPS . MEPS FAQ . MEPS SITE MAP . MEPS PRIVACY POLICY . ACCESSIBILITY . VIEWERS & PLAYERS . COPYRIGHT